Notes

// Substitutes the parameters in the string. The maximum number of the parameters is 9.
// Parameters in the string are specified as %<parameter number>. Parameter numbering starts with 1.
//
// Parameters:
// SubstitutionString – String – string pattern that includes parameters in the following format: %ParameterName;
// Parameter<n> - String - parameter to be substituted.
//
// Returns:
// String – string with substituted parameters.
//
// Example:
// SubstituteParametersInString(NStr("en='%1 went to %2'"), "John", "a zoo") = "John went to a zoo".
//
Function SubstituteParametersInString(Val SubstitutionString,
Val Parameter1, Val Parameter2 = Undefined, Val Parameter3 = Undefined,
Val Parameter4 = Undefined, Val Parameter5 = Undefined, Val Parameter6 = Undefined,
Val Parameter7 = Undefined, Val Parameter8 = Undefined, Val Parameter9 = Undefined) Export

If SubstitutionString = Undefined Or StrLen(SubstitutionString) = 0 Then
Return "";
EndIf;

Result = "";
StartPosition = 1;
Position = 1;
While Position <= StrLen(SubstitutionString) Do
StringChar = Mid(SubstitutionString, Position, 1);
If StringChar <> "%" Then
Position = Position + 1;
Continue;
EndIf;
Result = Result + Mid(SubstitutionString, StartPosition, Position - StartPosition);
Position = Position + 1;
StringChar = Mid(SubstitutionString, Position, 1);

If StringChar = "%" Then
Position = Position + 1;
StartPosition = Position;
Result = Result + "%";
Continue;
EndIf;

Try
ParameterNumber = Number(StringChar);
Except
Raise NStr("en='SubstitutionString source string has an invalid format: %'" + StringChar);
EndTry;

If StringChar = "1" Then
ParameterValue = Parameter1;
ElsIf StringChar = "2" Then
ParameterValue = Parameter2;
ElsIf StringChar = "3" Then
ParameterValue = Parameter3;
ElsIf StringChar = "4" Then
ParameterValue = Parameter4;
ElsIf StringChar = "5" Then
ParameterValue = Parameter5;
ElsIf StringChar = "6" Then
ParameterValue = Parameter6;
ElsIf StringChar = "7" Then
ParameterValue = Parameter7;
ElsIf StringChar = "8" Then
ParameterValue = Parameter8;
ElsIf StringChar = "9" Then
ParameterValue = Parameter9;
Else
Raise NStr("en='SubstitutionString source string has an invalid format: %'" + ParameterValue);
EndIf;
If ParameterValue = Undefined Then
ParameterValue = "";
Else
ParameterValue = String(ParameterValue);
EndIf;
Result = Result + ParameterValue;
Position = Position + 1;
StartPosition = Position;

EndDo;

If (StartPosition <= StrLen(SubstitutionString)) Then
Result = Result + Mid(SubstitutionString, StartPosition, StrLen(SubstitutionString) - StartPosition + 1);
EndIf;

Return Result;

EndFunction