Notes

CMD_WR EQU 0FF2CH
DATA_WR EQU 0FF2DH ;dziala
CMD_RD EQU 0FF2EH ;i miga diodkami
DATA_RD EQU 0FF2FH
INIT EQU 0038H
WLACZ EQU 0EH
CLEAR EQU 001H

TIME EQU 50
LOAD EQU (65536 - TIME * 1000)
COUNTER EQU 30H
SEC EQU 31H
MIN EQU 32H
HR EQU 33H

SEC_CHANGE EQU 0

ORG 0
SJMP main

;---
; OBSLUGA PRZERWANIA TIMERA
;---
ORG 0BH

MOV TL0, #LOW(LOAD)
MOV TH0, #HIGH(LOAD)
CPL P1.7
PUSH ACC
PUSH PSW

DJNZ COUNTER, koniec_przerwania ;SPRAWDZENIE LICZNIKA
MOV COUNTER, #20 ;JAK JEST ZERO TO DAJEMY 20

CPL P1.0
SETB SEC_CHANGE

INC SEC
MOV A, SEC
CJNE A, #60, koniec_przerwania
MOV SEC, #0

INC MIN
MOV A, MIN
CJNE A, #60, koniec_przerwania
MOV MIN, #0

INC HR
MOV A, HR
CJNE A, #24, koniec_przerwania
MOV HR, #0

koniec_przerwania:
POP PSW
POP ACC

RETI

main:
LCALL lcd_init
LCALL init_time
i:
JNB SEC_CHANGE, $
CLR SEC_CHANGE
LCALL lcd_write_time
SJMP i

;---
; odmierzanie 1s
;---

init_time:
MOV COUNTER, #20 ; 20*50ms = 1s
MOV HR, #0
MOV MIN, #0
MOV SEC, #0

SETB SEC_CHANGE ; ustawienie flagi zmiany czasu


CLR TR0
ANL TMOD, #0F0H ; zerujemy rejestr sterujacy
ORL TMOD, #1 ; ustawienie 16bit
MOV TL0, #LOW(LOAD)
MOV TH0, #HIGH(LOAD)
CLR TF0 ; zerujemy flage przepelnienia
SETB ET0 ; wlaczenie przerwania timera
SETB EA ; wlaczenie przerwan
SETB TR0 ; wlaczenie timera
RET

;---
; wyslanie komendy do wyswietlacza
;---

lcd_wr_cmd:

PUSH ACC
MOV DPTR, # CMD_RD

petla:
MOVX A, @DPTR
JB ACC.7, petla
MOV DPTR, #CMD_WR
POP ACC
MOVX @DPTR, A
RET

;----
; inicjalizacja wyswietlacza
;----

lcd_init:

MOV A, #INIT
LCALL lcd_wr_cmd
MOV A, #CLEAR
LCALL lcd_wr_cmd
MOV A, #WLACZ
LCALL lcd_wr_cmd
RET


;---
; wyslanie danych na wyswietlacz
;---

lcd_wr_data:

PUSH ACC
MOV DPTR, #CMD_RD

petla1:

MOVX A, @DPTR
JB ACC.7, petla1
MOV DPTR, #DATA_WR
POP ACC
MOVX @DPTR, A
RET
;---
; wysyla znak na ekran z akumulatora
;---

lcd_send_char:

LCALL lcd_wr_data
RET

;---
; idz do Y-R1, X-R0
;---

lcd_gotoxy:

MOV A, #40H
MOV B, R1
MUL AB
ADD A, R0
ADD A, #80H
lcall lcd_wr_cmd
RET

;---
; wyswietlanie liczby
;---

lcd_send_digits:
PUSH ACC
MOV B, #10
DIV AB
ADD A, #48
LCALL lcd_send_char
MOV A, B
ADD A, #48
LCALL lcd_send_char
POP ACC
RET

;---
; wypisz czas
;---
lcd_write_alarm:
MOV R0, #4
MOV R1, #1
LCALL lcd_gotoxy
MOV A, #'a'
LCALL lcd_send_char
MOV A, #'l'
LCALL lcd_send_char
MOV A, #'a'
LCALL lcd_send_char
MOV A, #'r'
LCALL lcd_send_char
MOV A, #'m'
LCALL lcd_send_char
RET


lcd_write_time:
MOV R0, #4
MOV R1, #0
LCALL lcd_gotoxy
;WYSWIETLANIE GODZINY
MOV A, HR
LCALL lcd_send_digits
;WYSWIETLANIE :
MOV A, #':'
LCALL lcd_send_char

MOV A, MIN
LCALL lcd_send_digits

MOV A, #':'
LCALL lcd_send_char

MOV A, SEC
LCALL lcd_send_digits

RET


END